home *** CD-ROM | disk | FTP | other *** search
/ TPUG - Toronto PET Users Group / TPUG Users Group CD / TPUG Users Group CD.iso / C64 / T-TPUG Old Monthly Disks / (c)tj.d64 / type it.c (.txt) < prev    next >
Commodore BASIC  |  2007-02-04  |  6KB  |  137 lines
  1. 0 POKE54296,15:FORL=1TO10:POKEL+54272,0:NEXT:SI=54272:W1=SI+4:W3=SI+18:V=SI+24:PW=SI+27
  2. 1 PRINT"[147]";:POKE53280,12:POKE53281,15:FORI=1024TO1063:POKEI,160:POKEI+54272,2:NEXT
  3. 2 PRINT"";:FORI=1TO22:PRINT"[145] [146]";SPC(38);" [146]":NEXT
  4. 3 POKE1944,160:POKE54272+1944,2:POKE1983,160:POKE54272+1983,2
  5. 4 FORI=1984TO2023:POKEI,160:POKEI+54272,2:NEXT:POKE54296,15
  6. 5 PRINT"TYPE IT!"
  7. 6 PRINT"[154]         BY SYD BOLTON"
  8. 7 PRINT"[144]COPYRIGHT (C) 1985 BY"
  9. 8 PRINT"OSTON SOFTWARE":PRINT"HIT A KEY OR WAIT";
  10. 9 A$="":DIMA$(50):FORI=1TO50:READA$(I):NEXT:WM=20:PE=SI+28:HS=0
  11. 10 FORI=1TO3000:GETA$:IFA$=""THENNEXT
  12. 20 PRINT:PRINT"[147]          WELCOME TO TYPE IT!"
  13. 30 PRINT"[144] I'LL GIVE YOU A SENTENCE AND YOU HAVE"
  14. 40 PRINT"TO TYPE IT AS FAST AS YOU CAN. I'LL TELL"
  15. 50 PRINT"YOU HOW MANY LETTERS PER MINUTE (LPM) &"
  16. 60 PRINT"HOW MANY WORDS PER MINUTE (WPM) THAT "
  17. 70 PRINT"YOU ARE TYPING AT."
  18. 80 PRINT" IF YOU ARE TYPING SLOW THEN I WILL LET"
  19. 90 PRINT"YOU QUIT. IF HOWEVER, YOU WANT TO "
  20. 100 PRINT"PRACTICE WITHOUT ME NAGGING AT YOU,"
  21. 110 PRINT"CHOOSE SKILL LEVEL #3"
  22. 120 PRINT"        [156]HIT ANY KEY TO CONTINUE"
  23. 130 POKE198,0:WAIT198,1:POKE198,0
  24. 140 PRINT"[147] [144]LEVEL #2 WILL FLASH THE SENTENCE FOR"
  25. 150 PRINT"ABOUT 2 SECONDS AND THEN DISAPPEAR. YOU"
  26. 160 PRINT"MUST THEN TYPE THE SENTENCE IN."
  27. 170 PRINT" LEVEL #1 WILL DISPLAY THE SENTENCE "
  28. 180 PRINT"CONTINUALLY."
  29. 181 PRINT" PRESS THE COMMODORE LOGO KEY FOR A "
  30. 182 PRINT"REPORT CARD."
  31. 190 PRINT"ENTER SKILL LEVEL (1-3)?";
  32. 191 GETB$:IFB$=""THEN191
  33. 192 LV=1:Q=1
  34. 195 B=VAL(B$):IFB<1ORB>3THEN191
  35. 200 R=INT(RND(1)*50)+1:K=1:L=LEN(A$(R))
  36. 201 PRINT"[147][144][213][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][201]"
  37. 202 PRINT"[145][221]               TYPE IT![144]               [221]"
  38. 203 PRINT"[145][202][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][203]"
  39. 204 PRINT"[144]WPM:";WP
  40. 205 PRINT"[145]";TAB(31);"[144]LPM:";LP
  41. 210 PRINT"":T=(40-LEN(A$(R)))/2
  42. 230 PRINT:PRINT"[144][213][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][201]"
  43. 240 PRINT"[145][221]                                      [221]"
  44. 250 PRINT"[145][202][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][203]":PRINT"[145][145][145]";
  45. 251 PRINT"[156]         HIT ANY KEY WHEN READY":POKE198,0
  46. 252 WAIT198,1:PRINT"[145]                               ":POKE198,0
  47. 253 PRINT"[145][145][145][145][145][145][145][145][145][145]";TAB(T);"";A$(R):IFB=2THENGOSUB300
  48. 254 PRINT"";:FORWW=1TOT:PRINT"";:NEXT
  49. 255 Z=TI
  50. 260 FORI=1TOLEN(A$(R)):GOSUB8000:K=K+1:NEXT
  51. 266 LP=INT(L*60/((TI-Z)/60)):WP=INT(LP/5)
  52. 267 IFWP<WMANDB=1THEN400
  53. 268 IFWP<WMANDB=2THEN400
  54. 269 IFLP<0THENLP=0
  55. 270 IFWP<0THENWP=0
  56. 271 SC=SC+WP:Q=Q+1:IFQ=5THEN700
  57. 272 IFWP>HSTHENHS=WP
  58. 275 GOTO200
  59. 300 FORI=1TO2000:NEXT:PRINT"[145]                                      ":POKE198,0:RETURN
  60. 400 PRINT"[147][144]IT APPEARS THAT YOU ARE FALLING BELOW":PRINT
  61. 410 PRINT"THE MINIMUM WPM. IF YOU WANT TO GO TO"
  62. 420 PRINT"LEVEL #3, HIT '3'. IF YOU WANT ME TO"
  63. 430 PRINT"REDUCE THE MINIMUM WPM, HIT 'R', AND IF"
  64. 440 PRINT"YOU WANT TO QUIT, HIT 'Q'"
  65. 450 PRINT"ENTER 3, R OR Q?"
  66. 460 GETA$:IFA$=""THEN460
  67. 470 IFA$="Q"THEN900
  68. 480 IFA$="R"THENWM=WM-10:LV=LV-2:IFLV<1THENLV=1:WM=20
  69. 490 IFA$="R"THENQ=0:GOTO200
  70. 500 IFA$="3"THENB=3:Q=0:GOTO200
  71. 510 GOTO460
  72. 700 POKE53280,0:POKE53281,0:PRINT"[147]":FORQQ=SITOPE:POKEQQ,0:NEXT
  73. 710 POKEW1+1,17:POKEW1+2,251:POKEW3+1,187:POKEW3+2,140:POKEV,143:POKEW3,17:POKEW3-3,15:POKEW1,19
  74. 720 POKEW3,129
  75. 730 FORQQ=1TO200:POKE54273,PEEK(54299):POKE646,QQ
  76. 735 PRINT"";TAB(6);"YOU HAVE COMPLETED LEVEL";LV
  77. 740 NEXT
  78. 750 POKEV,0:POKEW1,0:POKEW3,0
  79. 760 POKE53280,12:POKE53281,15:PRINT"[147][144]I AM NOW INCREASING THE SKILL LEVEL SO"
  80. 770 PRINT"THAT THE MINIMUN WPM WILL BE";WM+5
  81. 775 FORQQ=1TO2500:NEXT
  82. 776 PRINT"                [144][213][195][195][195][195][195][195][201]"
  83. 780 PRINT"[144]                [221]BONUS:[144][221]"
  84. 781 PRINT" [144]               [202][195][195][195][195][195][195][203]"
  85. 785 POKE54296,15:POKE54277,0:POKE54278,247
  86. 790 FORQQ=1TOHS*LV:PRINT"                  ";QQ
  87. 792 :POKE54276,17:POKE54273,40:POKE54272,0:FORT=1TO20:NEXT
  88. 795 POKE54276,16:NEXT
  89. 800 Q=0:LV=LV+1:WM=WM+5:SC=SC+HS*LV:FORL=1TO2500:NEXT:GOTO200
  90. 900 PRINT"[147][156]              REPORT CARD":PRINT"              [183][183][183][183][183][183][183][183][183][183][183]"
  91. 905 PRINT"[144]YOUR FINAL SCORE IS: ";SC
  92. 910 PRINT"[144]YOU MADE IT TO LEVEL:";LV
  93. 920 PRINT"[144]YOUR BEST WPM WAS:   ";HS
  94. 925 PRINT"[195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195]"
  95. 930 PRINT"ENTER [144]Y TO PLAY AGAIN, OR ANY OTHER KEY"
  96. 940 PRINT"TO QUIT"
  97. 950 PRINT"CHOICE?"
  98. 960 GETA$:IFA$=""THEN960
  99. 970 IFA$="Y"THENSC=0:Q=0:HS=0:WP=0:LP=0:LV=1:GOTO20
  100. 980 POKE53280,14:POKE53281,6:PRINT"[147][154]";:END
  101. 7999 STOP
  102. 8000 IN$="":PRINT" [157]";
  103. 8010 P=PEEK(209)+PEEK(210)*256+POS(0):CH=32:RC=128:TT=0
  104. 8020 POKEP,CH+RC:TT=TT+1:IFTT>5THENTT=0:RC=128-RC:GOTO8020
  105. 8025 IFPEEK(653)=2THENGOTO900
  106. 8030 GETX$:IFX$=""THEN8020
  107. 8071 IFX$=MID$(A$(R),K,1)THENGOTO8080
  108. 8072 POKE54296,15:POKE54277,45:POKE54278,165:POKE54276,33:POKE54273,6:POKE54272,5
  109. 8073 FORT=1TO200:NEXT:POKE54276,32:POKE54273,0:POKE54272,0:GOTO8010
  110. 8080 POKEP,CH:PRINTX$" [157]";:RETURN
  111. 60000 DATACOMPUTERS ARE ALOT OF FUN,XAVIER IS IN THE KITCHEN MAKING PIE
  112. 60010 DATAJOE IS BUILDING A HOUSE,CHUCK IS DRINKING A BEER
  113. 60020 DATASTEVE IS TAKING A SNOOZE,SOMEBODY IS TALKING ON THE PHONE
  114. 60030 DATAHER CAR WAS IN THE ACCIDENT,THE PICTURE FELL FROM THE WALL
  115. 60040 DATATHE TELEVISION WAS LEFT ON,I AM PLAYING TYPE IT
  116. 60050 DATAANSWER THE TELEPHONE,TURN OFF ALL THE LIGHTS PLEASE
  117. 60060 DATALET'S GO FOR A WALK,PAPER IS MADE FROM TREES
  118. 60070 DATATHAT IS NOT IN FASHION,TAKE THE DISK OUT OF THE DRIVE
  119. 60080 DATAYOU DON'T PLAY ENOUGH VIDEO GAMES,CHUCK WON BIG AT THE DOG TRACK
  120. 60090 DATAGARFIELD IS A FUNNY LITTLE CAT,I GOT HIGH SCORE ON PAC MAN
  121. 60100 DATASCHOOL WAS HARD WORK TODAY,CHARLIE BROWN EATS CHEERIOS
  122. 60110 DATAPITFALL IS A GREAT GAME,KITT IS A BONUS CAR
  123. 60120 DATAHAPPY DAYS IS ON THE TV,WE ARE GOING TO THE MOVIES
  124. 60130 DATAPLEASE GO DOWN AND GET ME A PAPER,WE SIGNED IN AT THE MOTEL
  125. 60140 DATAA FAKE BILL SURFACED AT THE STORE,JOE WENT TO KMART YESTERDAY
  126. 60150 DATAPLATINUM BLONDE ARE A GOOD GROUP,GHOSTBUSTERS WAS A GREAT MOVIE
  127. 60160 DATADINNER TASTED GOOD TONIGHT,TIME TO GO TO BED
  128. 60170 DATA7UP HAS NO CAFFEINE,THE DRAPES WEREN'T CLEANED
  129. 60180 DATATHE COMMODORE 64 IS A GREAT COMPUTER
  130. 60190 DATACHUCK OWES ALOT OF MONEY,I SUBSCRIBE TO COMPUTE! MAGAZINE
  131. 60200 DATATHE BED WAS MADE MESSILY,ARE YOU A MEMBER OF TPUG?
  132. 60210 DATATHE PROFESSOR ATE BAGELS FOR DINNER,STRONG WINDS WERE FORECAST
  133. 60220 DATATHE DOG TRACK IS OPEN TONIGHT,GO AND WAKE YOUR FATHER UP
  134. 60230 DATASHE ORDERED COFFEE AND A DOUGHNUT,SHARKY'S MACHINE IS ON TV NOW
  135. 60240 DATATHE ARCADE IS OPEN,I JUST PLAYED MS. PAC MAN
  136. 60250 DATATHIS IS THE LAST SENTENCE FOR TYPE IT
  137.